comments
	Mesurer la suréaction des agents aux signaux publics
	Camille Cornand  et Frank Heinemann
	MAJ 01/12/05 Pas de tableau et £str=4 traitement nouveau Calculs avec 1 décimale (x10)
	MAJ 30/05/05
	HTML Version Needs Regate 5.04 or higher as CLIENT and SERVER - also uses REAL calculations see CALCULF
	Dans le script il y a une version HTML et une version classique
	PB : valeurs initiales pour guessa1 et guessz1
	MAJ 11/05 Modif SPSIGNAL et z sur 50..450 et £V=10
	MAJ 18/04
	created : 14/04/2005
	tested  : Regate 6.08 -  because of HTML and htmget with ask="REALNUM" and real_digits=1 et real directive
	using dll : NONE
	simulation : OK
	artificial players : ???
	ANOMALIE : set(rr=1-0.75) mauvais  mais  set(rr=1.0-0.75) est OK
	UPDATED 10 janvier 2008
	updated 25 Fevrier 2009 - see Traitement-Fev09   Est=£xtr=2  SignPub=£sign=1 SignPriv=£sign=2
methods
	SERVER
		START
			real
			(£tr=0)send(J1,QADMIN)&send(J2,QADMIN)
			set(£eps=10)
			set(£v=20)   / Difficile a changer : voir tableau HTML
			//maintenant en parametre set(£cst=100) / constante de payoff
			random(z,4001)
			set(z=z+500)    / z sur 500   ..   4500
			set(z=z/10)
			sp(SPSIGNAL)
			set(y=zz) / indication publique
			sp(SPSIGNAL)
			set(x1=zz) / indication privée joueur 1
			sp(SPSIGNAL)
			set(x2=zz) / indication privée joueur 2
			send(J1,SGHTML,z,x1,x2,y,£cst,£v,£r,£fx,£fy,£sim,£str,£sign)&send(J2,SGHTML,z,x1,x2,y,£cst,£v,£r,£fx,£fy,£sim,£str,£sign)    / Version HTML
		SPSIGNAL
			/ Entrée : z  Sortie : zz
			set(d=(10*2*£eps)+1)
			random(zz,d)
			set(zz=zz/10)
			set(zz=zz+z-£eps) / y range [z-£eps .. z+£eps]
			return
		CALCULGAINS
			/== Verifier pas d problemes avec gains en REELS ==
			join
			(£str=2)send(SERVER,CALCULGAINSNOUVEAU)
			/ Calcul des gains de joueur 1
			set(ai=a1)&set(ab=a2)
			sp(CALCULF)
			set(g1=f)
			/
			/ Calcul des gains du joueur 2
			set(ai=a2)&set(ab=a1)
			sp(CALCULF)
			set(g2=f)
			/
			send(J1,INFOGAINS,g1,a2)&send(J2,INFOGAINS,g2,a1)
		CALCULGAINSNOUVEAU
			/ depuis Fev09 on a £xtr=1=2008 et £xtr=2=2009
			real
			/ gains du joueur 1
			set(ga1=£cst-((repz1-z)*(repz1-z)))            / 2009
			set(gb1=£cst-((repe1-repz2)*(repe1-repz2)))  / 2009
			if(£xtr=1)set(g1=£cst-((repz1-z)*(repz1-z))-((repe1-repz2)*(repe1-repz2)))
			if(£xtr=2)set(g1=ga1+gb1)
			/ gains du joueur 2
			set(ga2=£cst-((repz2-z)*(repz2-z)))                / 2009
			set(gb2=£cst-((repe2-repz1)*(repe2-repz1)))    / 2009
			if(£xtr=1)set(g2=£cst-((repz2-z)*(repz2-z))-((repe2-repz1)*(repe2-repz1)))
			if(£xtr=2)set(g2=ga2+gb2)
			send(J1,INFOGAINSNOUVEAU,g1,ga1,gb1,repz2,repe2,£xtr)&send(J2,INFOGAINSNOUVEAU,g2,ga2,gb2,repz1,repe1,£xtr)
		END
			join
			/==Exemple syntaxe trace avec j et heu avec j1 et j2
			forallj:set(m=£machines^[£cnj])&set(group=£group^[£cnj])&trace([m] z [z] y [y] x [xj]  group [group] décision [aj] décisions [a$] estimation-de-z [repzj] estimation-de-autre [repej] estimations-de-z [repz$] estimations-de-autre [repe$] gain [gj]  )
			roundend
		ENDQADMIN
			join
			forallj:set(nom=£machines^[£cnj])&trace([nom] [aqj]) / Exemple syntaxe
			roundend
	J1
		SGHTML
			/ ==== Version HTML ====
			interface(feedback,colwidth=30,firstcolwidth=200)
			(£str=1,£sign=0)feedback(Période,Indication commune Y,Indication propre X,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain)
			(£str=1,£sign=1)feedback(Période,Indication commune Y,-,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain)
			(£str=1,£sign=2)feedback(Période,-,Indication propre X,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain)
			(£str=2)feedback(Période,Indication commune Y,Indication propre X,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain-1,Gain-2,Gain,Votre estimation de Z,Votre estimation de l'autre sur Z,Estimation de l'autre participant sur Z,Estimation de l'autre de votre estimation) 
			htmtell()
			/ Initialisation
			set(guessz1="?")&set(guessa1="?") / Valeurs initiales => pour pas d'init du tableau
			set(vua="text")&set(vub="text")&set(texta="Entrez votre estimation de Z")   /  type input : text ou hidden
			set(textb="Votre estimation de la décision de l'autre participant")
			(£r="0")set(vua="hidden")&set(texta="-")&set(guessz1=z)
			(£r="1")set(vub="hidden")&set(textb="-")&set(guessa1=z)
			set(nup1=0)&set(pguessa1="-")&set(pguessz1="-")
			set(vmin=y-£v)&set(vmax=y+£v) 
			set(m=y)  / Plus centré sur la moyenne mais sur Y
			send(J1,REFRESH)
		REFRESH
			(guessa1<>"?",guessz1<>"?")set(ini=0)#set(ini=1)
			(ini=1)sp(SPAFFICHAGEHTMLJ1INITIAL)
			(ini=0)sp(SPAFFICHAGEHTMLJ1)
			/ask(ALT,q,Update,OK,1,2) abandonned
			ask(OK)
			set(q=2)
			set(pguessz1=guessz1)&set(pguessa1=guessa1)
			/(q=1)htmget(ok,guessz,guessa)&set(guessz1=guessz)&set(guessa1=guessa)
			/(q=1)set(nup1=nup1+1)
			/(q=1)send(J1,REFRESH)    / Refresh
			(£str=1)htmget(ok,repa)
			(£str=2)htmget(ok,repz,repe)
			(ok=0)send(J1,REFRESH)
			(£str=1)set(a1=repa)&set(nup1=0)&set(repe1="-")&set(repz1="-")
			(£str=2)set(a1="-")&set(nup1="-")&set(repe1=repe)&set(repz1=repz)
			htmtell(<BR><font color=red>    Patientez SVP</font>)
			send(SERVER,CALCULGAINS,guessa1,guessz1,a1,nup1,pguessz1,pguessa1,repz1,repe1)
		SPAFFICHAGEHTMLJ1INITIAL
			htmtell()
			foralli:set(l[i]="?")&set(p[i]="?")    / initialisation variables du tableau pour pas de preselection
			real&set(x=x1)&set(guessz=guessz1)&set(guessa=guessa1)&integer
			/set(xpe=x/10)&set(ype=y/10)&set(xd=x-(xpe*10))&set(yd=y-(ype*10))  / HTML3 affiche xd et yd avec 1 decimale
			/set(vminpe=vmin/10)&set(vmind=vmin-(10*vminpe))&set(vmaxpe=vmax/10)&set(vmaxd=vmax-(10*vmaxpe))
			(£str=1,£sign=0)htmtell(HTML3)  / ancien avec sign  public et privé
			(£str=1,£sign=1)htmtell(HTML5)  / ancien mais signa public
			(£str=1,£sign=2)htmtell(HTML6)  / ancien mais sign privé
			(£str=2)htmtell(HTML4) / Nouveau
			return
		SPAFFICHAGEHTMLJ1
			/ Variables implicites :  y,x1,guessz1,guessa1,£v,£cst
			htmtell()
			set(m=y)   
			foralli:set(l=m-£v+[i]-1)&set(p=£cst-(£aa*(l-guessz1)*(l-guessz1)/£bb)-(£aaa*(l-guessa1)*(l-guessa1)/£bbb))&set(l[i]=l)&set(p[i]=p) / exemple syntaxe
			real&set(x=x1)&set(guessz=guessz1)&set(guessa=guessa1)&integer
			/ ATTENTION traitement avec r=0 ou r=1 il faut supprimer une ligne
			/set(xpe=x/10)&set(ype=y/10)&set(xd=x-(xpe*10))&set(yd=y-(ype*10))  / HTML3 affiche xd et yd avec 1 decimale
			/set(vminpe=vmin/10)&set(vmind=vmin-(10*vminpe))&set(vmaxpe=vmax/10)&set(vmaxd=vmax-(10*vmaxpe))
			(£str=1)htmtell(HTML3)   
			(£str=2)htmtell(HTML4)
			return
		SPAFFICHAGE
			/ Affichage standard : Variables implicites :  y,x1,guessz1,guessa1,£v,£cst
			tell()
			tell(Vous recevez deux valeurs indicatives sur le nombre inconnu Z :)
			tell(La valeur indicative commune est la meme pour vous et l'autre participant  :  Y = [y])
			tell(La valeur indicative que vous recevez en propre est  :                                           X = [x1])
			tell(Votre estimation de la vraie valeur de Z est :                  [guessz1])
			tell(Votre estimation du choix A de l'autre participant est : [guessa1])
			tell(Si vos estimations sont correctes les gains associés à votre décision sont donnés par le tableau suivant :)
			set(m=(y+x1)/2)&set(tabl1="Votre décision ")&set(tabl2="Votre gain ")
			foralli:set(l=m-£v+[i]-1)&set(p=£cst-(1*(l-guessz1)*(l-guessz1)/2)-(1*(l-guessa1)*(l-guessa1)/2))&set(tabl1="[tabl1][£char9][l]")&set(tabl2="[tabl2][£char9][p]")  / Exemple syntaxe avec tabulation
			tell(A2,[tabl1])
			tell(A2,[tabl2])
			return
		INFOGAINS
			tell(Votre gain est [g1])
			registergain(g1)
			gains(SUM,ggj,register,0,0.0040,0,Euros,blind)
			(£r="1")set(z="-")
			(£r="0")set(a2="-")
			if(£sign=0)feedbackupdate([y],[x1],[a1],[z],[a2],[g1])
			if(£sign=1)feedbackupdate([y],-,[a1],[z],[a2],[g1])
			if(£sign=2)feedbackupdate(-,[x1],[a1],[z],[a2],[g1])
			tell(*Patientez SVP)
			send(SERVER,END,ggj)
		INFOGAINSNOUVEAU
			interface(textbox,fontsize=12)
			if(£xtr=1)tell(Votre gain est [g1])
			if(£xtr=2)tell(Votre gain-1 est [ga1]  votre gain-2 est [gb1]    donc  votre gain total pour la période est [g1])
			registergain(g1)
			gains(SUM,ggj,register,0,0.0040,0,Euros,blind)
			if(£xtr=1)feedbackupdate([y],[x1],-,[z],-,-,-,[g1],[repz1],[repe1],[repz2],[repe2])
			if(£xtr=2)feedbackupdate([y],[x1],-,[z],-,[ga1],[gb1],[g1],[repz1],[repe1],[repz2],[repe2])
			tell(*Patientez SVP)
			send(SERVER,END,ggj)
		QADMIN
			sp(ADMINQUEST)
			set(aqj=rep)
			send(SERVER,ENDQADMIN,aqj)
	J2
		SGHTML
			/ === Version HTML
			interface(feedback,colwidth=30,firstcolwidth=200)
			(£str=1,£sign=0)feedback(Période,Indication commune Y,Indication propre X,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain)
			(£str=1,£sign=1)feedback(Période,Indication commune Y,-,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain)
			(£str=1,£sign=2)feedback(Période,-,Indication propre X,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain)
			(£str=2)feedback(Période,Indication commune Y,Indication propre X,Décision,Vraie valeur de Z,Décision de l'autre participant,Gain-1,Gain-2,Gain,Votre estimation de Z,Votre estimation de l'autre sur Z,Estimation de l'autre participant sur Z,Estimation de l'autre de votre estimation) 
			htmtell()
			/ Initialisation
			set(guessz2="?")&set(guessa2="?") / Valeurs initiales => pour pas d'init du tabelau
			set(vua="text")&set(vub="text")&set(texta="Entrez votre estimation de Z")   /  type input : text ou hidden
			set(textb="Votre estimation de la décision de l'autre participant")
			(£r="0")set(vua="hidden")&set(texta="-")&set(guessz2=z)
			(£r="1")set(vub="hidden")&set(textb="-")&set(guessa2=z)
			set(nup2=0)&set(pguessa2="-")&set(pguessz2="-")
			set(vmin=y-£v)&set(vmax=y+£v)
			set(m=y)  / Plus centré sur la moyenne mais sur Y
			send(J2,REFRESH)
		REFRESH
			(guessa2<>"?",guessz2<>"?")set(ini=0)#set(ini=1)
			(ini=1)sp(SPAFFICHAGEHTMLJ2INITIAL)
			(ini=0)sp(SPAFFICHAGEHTMLJ2)
			/ask(ALT,q,Update,OK,1,2)
			(£sim=0)ask(OK)
			/(£sim=1)ask(NUM,repa,300,0)
			set(q=2)
			set(pguessz2=guessz2)&set(pguessa2=guessa2)
			/(q=1)htmget(ok,guessz,guessa)&set(guessz2=guessz)&set(guessa2=guessa)
			/(q=1)set(nup2=nup2+1)
			/(q=1)send(J2,REFRESH)    / Refresh
			(£sim=0,£str=1)htmget(ok,repa)
			(£sim=0,£str=2)htmget(ok,repz,repe)
			(£sim=1,£str=1)set(repa=y) / provisoire
			(£sim=1,£str=2)set(repz=y)&set(repe=y)   / provisoire
			(£sim=1)set(ok=1)
			(ok=0)send(J2,REFRESH)
			(£str=1)set(a2=repa)&set(nup2=0)&set(repe2="-")&set(repz2="-")
			(£str=2)set(a2="-")&set(nup2="-")&set(repe2=repe)&set(repz2=repz)
			htmtell(<BR><font color=red>    Patientez SVP</font>)
			send(SERVER,CALCULGAINS,guessa2,guessz2,a2,pguessa2,pguessz2,repe2,repz2)
		SPAFFICHAGEHTMLJ2INITIAL
			htmtell()
			foralli:set(l[i]="?")&set(p[i]="?")    / initialisation variables du tableau pour pas de preselection
			real&set(x=x2)&set(guessz=guessz2)&set(guessa=guessa2)&integer
			/set(xpe=x/10)&set(ype=y/10)&set(xd=x-(xpe*10))&set(yd=y-(ype*10))  / HTML3 affiche xd et yd avec 1 decimale
			/set(vminpe=vmin/10)&set(vmind=vmin-(10*vminpe))&set(vmaxpe=vmax/10)&set(vmaxd=vmax-(10*vmaxpe))
			(£str=1,£sign=0)htmtell(HTML3)   
			(£str=1,£sign=1)htmtell(HTML5)   
			(£str=1,£sign=2)htmtell(HTML6)   
			(£str=2)htmtell(HTML4)
			return
		SPAFFICHAGEHTMLJ2
			/ Variables implicites :  y,x1,guessz1,guessa1,£v,£cst
			htmtell()
			set(m=y)
			foralli:set(l=m-£v+[i]-1)&set(p=£cst-(£aa*(l-guessz2)*(l-guessz2)/£bb)-(£aaa*(l-guessa2)*(l-guessa2)/£bbb))&set(l[i]=l)&set(p[i]=p) / exemple syntaxe
			real&set(x=x2)&set(guessz=guessz2)&set(guessa=guessa2)&integer
			/ ATTENTION traitement avec r=0 ou r=1 il faut supprimer une ligne
			/set(xpe=x/10)&set(ype=y/10)&set(xd=x-(xpe*10))&set(yd=y-(ype*10))  / HTML3 affiche avec 1 decimale
			/set(vminpe=vmin/10)&set(vmind=vmin-(10*vminpe))&set(vmaxpe=vmax/10)&set(vmaxd=vmax-(10*vmaxpe))
			(£str=1)htmtell(HTML3) 
			(£str=2)htmtell(HTML4)
			return
		INFOGAINS
			tell(Votre gain est [g2])
			registergain(g2)
			gains(SUM,ggj,register,0,0.0040,0,Euros,blind)
			(£r="1")set(z="-")
			(£r="0")set(a1="-")
			if(£sign=0)feedbackupdate([y],[x2],[a2],[z],[a1],[g2])
			if(£sign=1)feedbackupdate([y],-,[a2],[z],[a1],[g2])
			if(£sign=2)feedbackupdate(-,[x2],[a2],[z],[a1],[g2])
			tell(*Patientez SVP)
			send(SERVER,END,ggj)
		INFOGAINSNOUVEAU
			interface(textbox,fontsize=12)
			if(£xtr=1)tell(Votre gain est [g2])
			if(£xtr=2)tell(Votre gain-1 est [ga2]  votre gain-2 est [gb2]   donc votre gain total pour la période est [g2])
			registergain(g2)
			gains(SUM,ggj,register,0,0.0040,0,Euros,blind)
			if(£xtr=1)feedbackupdate([y],[x2],-,[z],-,-,-,[g2],[repz2],[repe2],[repz1],[repe1])
			if(£xtr=2)feedbackupdate([y],[x2],-,[z],-,[ga2],[gb2],[g2],[repz2],[repe2],[repz1],[repe1])
			tell(*Patientez SVP)
			send(SERVER,END,ggj)
		QADMIN
			sp(ADMINQUEST)
			set(aqj=rep)
			send(SERVER,ENDQADMIN,aqj)
	SP
		CALCULF
			/ Entrée : z, ai, ab pondéres suivant traitement
			/====Avec des fractions  £rn/£rd et £rrn/£rrd
			real
			set(pt=£fx*(ai-z)*(ai-z))         
			set(dt=£fy*(ai-ab)*(ai-ab)) 
			set(f=£cst-pt-dt)
			/ Sortie : f
			return
		ADMINQUEST
			/ Questionnaire administratif Out : rep
			interface(textbox,visible=0)
			interface(feedback,visible=0)
			tell()
			tell(*Quel est votre age ?)
			ask(NSB,age,70,18,Age = [age])
			tell(*Quel est votre sexe ?)
			ask(ALT,sexe,Homme,Femme,1,0)
			ask(CUSTOM,nivet,RadioButton,Quel est votre niveau d'études ?,Moins que le bac,Bac,Bac+2,Bac+3,Bac+4,Bac+5,Au dela)
			ask(CUSTOM,status,RadioButton,Etes vous ?,Salarié,Chômeur,Etudiant)
			set(Ecole="-")
			(status=3)ask(CUSTOM,ecole,RadioButton,Vous êtes étudiant à ?,Itech,EM-Lyon,EC-Lyon,Faculté de Sciences Economiques,Autre)
			ask(CUSTOM,disc,RadioButton,Quelle est votre discipline actuelle ?,Sciences Économiques,Génie,Gestion,Sciences Politiques, Psychologie,MASS,Mathématiques, Informatique,Sociologie,Biologie, Chimie, Médecine,Autres)
			tell(*Avez vous déjà participé à une expérience ?)
			ask(ALT,expe,OUI,NON,1,0)
			interface(interaction,visible=0)
			set(rep="[age];[sexe];[nivet];[disc];[expe];[status];[ecole]")
			return
texts
	french
		A1
			blue,10
		A2
			black,8
		ST1
			Votre réponse :
		ST2
			Information :
		ST3
			Période N° 
		HTML2
			<head><style type="text/css">table {font-family : "Times"; font-size=8 }</style></head>
		HTML3
			<HTML>
			<BODY>
			<head><style type="text/css">table { font-size=10}</style></head>
			<font size="2">
			Vous recevez deux valeurs indicatives sur le nombre inconnu <strong>Z</strong>:
			<BR>La valeur indicative commune est :<strong>Y = [y]</strong>  La valeur indicative que vous recevez en propre est :<strong> X =[x]</strong>
			<HR>
			Entrez ici votre décision  :
			<INPUT style="WIDTH: 113px; HEIGHT: 22px" size=14 maxlength=5 name="repa" ask="REALNUM" min="[vmin]" max="[vmax]" value="">
			<HR>
			<BR>Puis cliquez le bouton <strong>OK</strong>
			</font>
			</BODY>
			</HTML>
		HTML4
			<HTML>
			<BODY>
			<head><style type="text/css">table { font-size=10}</style></head>
			<font size="2">
			Vous recevez deux valeurs indicatives sur le nombre inconnu <strong>Z</strong>:
			<BR>La valeur indicative commune est :<strong>Y = [y]</strong>  La valeur indicative que vous recevez en propre est :<strong> X =[x]</strong>
			<HR>
			Entrez ici votre estimation de Z  :
			<INPUT style="WIDTH: 113px; HEIGHT: 22px" size=14 maxlength=5 name="repz" ask="REALNUM" min="[vmin]" max="[vmax]" value="">
			
			<BR>Entrez ici votre estimation de l'estimation de l'autre participant sur Z :
			<INPUT style="WIDTH: 113px; HEIGHT: 22px" size=14 maxlength=5 name="repe" ask="REALNUM" min="[vmin]" max="[vmax]" value="">
			<HR>
			<BR>Puis cliquez le bouton <strong>OK</strong>
			</font>
			</BODY>
			</HTML>
		HTML5
			<HTML>
			<BODY>
			<head><style type="text/css">table { font-size=10}</style></head>
			<font size="2">
			Vous recevez une valeur indicative sur le nombre inconnu <strong>Z</strong>:
			<BR>Cette valeur indicative est commune à vous et la personne qui vous est appariée:<strong>Y = [y]</strong> 
			<HR>
			Entrez ici votre décision  :
			<INPUT style="WIDTH: 113px; HEIGHT: 22px" size=14 maxlength=5 name="repa" ask="REALNUM" min="[vmin]" max="[vmax]" value="">
			<HR>
			<BR>Puis cliquez le bouton <strong>OK</strong>
			</font>
			</BODY>
			</HTML>
		HTML6
			<HTML>
			<BODY>
			<head><style type="text/css">table { font-size=10}</style></head>
			<font size="2">
			Vous recevez une valeur indicative sur le nombre inconnu <strong>Z</strong>:
			<BR>Cette valeur indicative que vous recevez en propre (privée) est :<strong> X =[x]</strong>
			<HR>
			Entrez ici votre décision  :
			<INPUT style="WIDTH: 113px; HEIGHT: 22px" size=14 maxlength=5 name="repa" ask="REALNUM" min="[vmin]" max="[vmax]" value="">
			<HR>
			<BR>Puis cliquez le bouton <strong>OK</strong>
			</font>
			</BODY>
			</HTML>
	english
		ST1
			Your answer :
		ST2
			Feedback information
		ST3
			Now playing round N° 
range
	guessa
		0..100
	guessz
		0..100
	repa
		0..100
	q
		1,2
	ok
		0,1
	i
		1..41
artificial
settings
	groupsize
		2
		12
	roles
		J1=Joueur1
		J2=Joueur2
	traces
		TRx
		cornand@gate.cnrs.fr
		opt=secure-traces
	language
		french
	grouping
		shuffle
	experiments
		Session-2009-Public
			"Traitement-0"5,£tr=1,£r=0,£fx=1,£fy=0,£cst=100,£str=1,£sign=0
			"Traitement-Fev09-Est"5,£tr=1,£r=1,£fx=1,£fy=1,£cst=100,£str=2,£xtr=2,£sign=0
			"Traitement-1-SignPub"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=1
			"Traitement-0.5"20,£tr=1,£r=0.5,£fx=1,£fy=1,£cst=200,£str=1,£sign=0
			"Traitement-1"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=0
			"Quest-Admin"1,£tr=0
		Session-2009-Privé
			"Traitement-0"5,£tr=1,£r=0,£fx=1,£fy=0,£cst=100,£str=1,£sign=0
			"Traitement-Fev09-Est"5,£tr=1,£r=1,£fx=1,£fy=1,£cst=100,£str=2,£xtr=2,£sign=0
			"Traitement-1-SignPriv"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=2
			"Traitement-0.5"20,£tr=1,£r=0.5,£fx=1,£fy=1,£cst=200,£str=1,£sign=0
			"Traitement-1"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=0
			"Quest-Admin"1,£tr=0
	sessions
		"Quest-Admin"1,£tr=0
		"Traitement-0.5"20,£tr=1,£r=0.5,£fx=1,£fy=1,£cst=200,£str=1,£sign=0
		"Traitement-0.75"30,£tr=1,£r=0.75,£fx=1,£fy=3,£cst=400,£str=1,£sign=0
		"Traitement-0.25"30,£tr=1,£r=0.25,£fx=3,£fy=1,£cst=400,£str=1,£sign=0
		"Traitement-0"5,£tr=1,£r=0,£fx=1,£fy=0,£cst=100,£str=1,£sign=0
		"Traitement-1"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=0
		"Traitement-nouveau"5,£tr=1,£r=1,£fx=1,£fy=1,£cst=100,£str=2,£xtr=1,£sign=0
		"Traitement-Fev09-Est"5,£tr=1,£r=1,£fx=1,£fy=1,£cst=100,£str=2,£xtr=2,£sign=0
		"Traitement-1-SignPub"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=1
		"Traitement-1-SignPriv"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=2
	parameters
		"Traitement-0"5,£tr=1,£r=0,£fx=1,£fy=0,£cst=100,£str=1,£sign=0
		"Traitement-Fev09-Est"5,£tr=1,£r=1,£fx=1,£fy=1,£cst=100,£str=2,£xtr=2,£sign=0
		"Traitement-1-SignPub"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=1
		"Traitement-0.5"20,£tr=1,£r=0.5,£fx=1,£fy=1,£cst=200,£str=1,£sign=0
		"Traitement-1"10,£tr=1,£r=1,£fx=0,£fy=1,£cst=100,£str=1,£sign=0
		"Quest-Admin"1,£tr=0
	rounds
		10
	serverfeedback
	misc
		j=relative_client_number
		real_digits=1
variables
	£sim=mode
	£nr=round number
	£ns=session number
	£pj=parameters
	£np=players per group
	£maxnr=?
	£lg=?
	£r=?
	£aa=?
	£bb=?
	£aaa=?
	£bbb=?
	£eps=?
	£v=?
	£cst=?
	z=?
	d=?
	zz=?
	y=?
	xj=?
	guessaj=?
	guesszj=?
	aj=?
	nupj=?
	pguesszj=?
	pguessaj=?
	ai=?
	ab=?
	pt=?
	dt=?
	f=?
	gj=?
